source: GTP/trunk/App/Demos/Illum/IBRBillboardCloudTrees/OGRE/IBRTreesOGRE/media/oldgeneral/ground_fp.txt @ 1493

float backProjectionCut;
float Ka;
float Kd;
float Ks;
float4 platformColor;
float shadowBias;
sampler ShadowMapLeaves;
sampler SpotLight;
sampler PlataformMap;

float4 main( float3 normal: TEXCOORD0, 
             float3 lightVec: TEXCOORD1, 
             float3 viewVec: TEXCOORD2, 
             float4 shadowCrd: TEXCOORD3,
             float3 texCoord: TEXCOORD4) : COLOR 
{
   normal = normalize(normal);
   
   // Radial distance
   float depth = length(lightVec);
   // Normalizes light vector
   lightVec /= depth;

   // Standard lighting
   float diffuse = saturate(dot(lightVec, normal));
   float specular = pow(saturate(dot(reflect(-normalize(viewVec), normal), lightVec)), 16);

   // The depth of the fragment closest to the light
   float fShadowMapLeaves = tex2Dproj(ShadowMapLeaves, shadowCrd).x;
   // A spot image of the spotlight
   float spotLight = tex2Dproj(SpotLight, shadowCrd);
   // If the depth is larger than the stored depth, this fragment
   // is not the closest to the light, that is we are in shadow.
   // Otherwise, we're lit. Add a bias to avoid precision issues.
   float shadow;
   shadow = (depth < fShadowMapLeaves + shadowBias);
  
   // Cut back-projection, that is, make sure we don't lit
   // anything behind the light. Theoretically, you should just
   // cut at w = 0, but in practice you'll have to cut at a
   // fairly high positive number to avoid precision issue when
   // coordinates approaches zero. 
   shadow *= (shadowCrd.w > backProjectionCut);
   // Modulate with spotlight image
   shadow *= spotLight;

   // Shadow any light contribution except ambient
   //return Ka * platformColor + (Kd * diffuse * platformColor + Ks * specular) * shadow;
   return Ka * tex2D(PlataformMap,texCoord) + (Kd * diffuse * platformColor + Ks * specular) * shadow;
   
}