source: GTP/trunk/App/Demos/Illum/Shark3D/version164x12u/IllumDemo/src/res/levelutil/shader/prog/d3d9_hlsl/standard_d3d9_hlsl_vs1x1.s3d_shadercode @ 2196

///////////////////////////////////////////////////////////////////////////////
//
//      ##  ######
//       ######  ###
//  ## ###############        Shark 3D Engine (www.shark3d.com)
//   ########## # # #
//    ########                Copyright (c) 1996-2006 Spinor GmbH.
//   ######### # # #          All rights reserved.
//  ##   ##########
//      ##
//
///////////////////////////////////////////////////////////////////////////////

#include \
    <levelutil/shader/prog/d3d9_hlsl/include_stddef_d3d9_hlsl.s3d_shadercode_run>

///////////////////////////////////////////////////////////////////////////////

struct VS_INPUT
{
    float4 posObj: POSITION;
    float3 normalObj: NORMAL;
    S3D_BONE_DECL_STD(boneWgh, boneSubscr)
    float2 mainTexCoord: TEXCOORD0;
};

struct VS_OUTPUT
{
    float4 posScr: POSITION;
    float2 mainTexCoord: TEXCOORD0;
    float4 diffuse: COLOR0;
    float4 specular: COLOR1;
    float fogCoord: TEXCOORD2;
};

///////////////////////////////////////////////////////////////////////////////

const float4x4 projMat;

S3D_MATBONE_DECL_STD(matBone)

const float4 mtrlPower;
const float4 mtrlEmissive;

const s3d_StdProgLight lightArray[S3D_LIGHT_CNT];
const int activeLights;

///////////////////////////////////////////////////////////////////////////////
// Vertexshader
// Profile: 1x1

VS_OUTPUT main(VS_INPUT input)
{
    VS_OUTPUT output = (VS_OUTPUT)0;

    float4x4 matBoneFinal;
    S3D_BONE_TRANSF_STD(
            matBoneFinal, matBone, input.boneWgh, input.boneSubscr);
    // Transform vectors by matBoneFinal
    float4 posView = mul(input.posObj, matBoneFinal);
    float3 normalView = normalize(mul(input.normalObj, matBoneFinal).xyz);

    output.posScr = mul(posView, projMat);
    output.mainTexCoord = input.mainTexCoord;
    output.fogCoord = posView.z / posView.w;

    float4 colDiffuse = mtrlEmissive;
    float4 colSpecular = (float4)0;
    for(int i = 0; i < S3D_LIGHT_CNT; i++)
    {
        s3d_ColPair lightCol = s3d_calcPointLightTerm(
                posView.xyz, normalView, mtrlPower.w, lightArray[i]);
        colDiffuse += lightCol.diffuse;
        colSpecular += lightCol.specular;
    }

    output.diffuse = colDiffuse;
    output.specular = colSpecular;

    return output;
}

///////////////////////////////////////////////////////////////////////////////