source: GTP/trunk/App/Demos/Vis/FriendlyCulling/src/shaders/ssao.cg @ 2991

#include "../shaderenv.h"

////////////////////
// Screen Spaced Ambient Occlusion shader
// based on shader of Alexander Kusternig


struct fragment
{
         // normalized screen position
        float4 pos: WPOS;
        float2 texCoord: TEXCOORD0; 
        float3 view: TEXCOORD1;
};


struct pixel
{
        float4 illum_col: COLOR0;
};


inline float2 myreflect(float2 pt, float2 n)
{
        // distance to plane
        float d = dot(n, pt);
        // reflect around plane
        float2 rpt = pt - d * 2.0f * n;

        return rpt;
}


inline float3 Interpol(float2 w, float3 bl, float3 br, float3 tl, float3 tr)
{
        float3 x1 = lerp(bl, tl, w.y);
        float3 x2 = lerp(br, tr, w.y); 
        float3 v = lerp(x1, x2, w.x); 

        return v;
}


inline float3 ReconstructSamplePosition(float3 eyePos, 
                                                                                uniform sampler2D colors,
                                                                                float2 texcoord, 
                                                                                float3 bl, float3 br, float3 tl, float3 tr)
{
        /*float eyeSpaceDepth = tex2Dlod(colors, float4(texcoord, 0, SSAO_MIPMAP_LEVEL)).w;
                
        // reconstruct world space position
        float3 rotView = normalize(Interpol(texcoord, bl, br, tl, tr));
        float3 sample_position = eyePos - rotView * eyeSpaceDepth;*/
        float3 sample_position = tex2Dlod(colors, float4(texcoord, 0, SSAO_MIPMAP_LEVEL)).xyz;

        return sample_position;
}


/** The ssao shader returning the an intensity value between 0 and 1
*/
float2 ssao(fragment IN,
                   uniform sampler2D colors,
                   uniform sampler2D noiseTexture,
                   uniform float2 samples[NUM_SAMPLES],
                   uniform float3 currentNormal,
                   uniform float4 centerPosition,
                   uniform float scaleFactor,
                   //uniform float3 viewDir,
                   uniform float3 eyePos,
                   uniform float3 bl,
                   uniform float3 br,
                   uniform float3 tl,
                   uniform float3 tr
                   )
{
        // Check in a circular area around the current position.
        // Shoot vectors to the positions there, and check the angle to these positions.
        // Summing up these angles gives an estimation of the occlusion at the current position.

        float total_ao = 0.0;
        float numSamples = 0;


        for (int i = 0; i < NUM_SAMPLES; ++ i) 
        {
                const float2 offset = samples[i];

#if 1
                ////////////////////
                // add random noise: reflect around random normal vector (warning: slow!)

                float2 mynoise = tex2D(noiseTexture, IN.texCoord.xy).xy;
                const float2 offsetTransformed = myreflect(offset, mynoise);
#else
                const float2 offsetTransformed = offset;
#endif
                // weight with projected coordinate to reach similar kernel size for near and far
                float2 texcoord = IN.texCoord.xy + offsetTransformed * AREA_SIZE * scaleFactor;

                if ((texcoord.x <= 1.0f) && (texcoord.x >= 0.0f) && (texcoord.y <= 1.0f) && (texcoord.y >= 0.0f))
                        ++ numSamples;

                float3 sample_position = ReconstructSamplePosition(eyePos, colors, texcoord, bl, br, tl, tr);

                float3 vector_to_sample = sample_position - centerPosition.xyz;
                const float length_to_sample = length(vector_to_sample);

                float3 direction_to_sample = vector_to_sample / length_to_sample;

                // angle between current normal and direction to sample controls AO intensity.
                const float cos_angle = max(dot(direction_to_sample, currentNormal), 0.0f);

                // the distance_scale offset is used to avoid singularity that occurs at global illumination when 
                // the distance to a sample approaches zero
                const float distance_intensity = 
                        (SAMPLE_INTENSITY * DISTANCE_SCALE) / (DISTANCE_SCALE + length_to_sample * length_to_sample);

#if 0
                // if surface normal perpenticular to view dir, approx. half of the samples will not count
                // => compensate for this (on the other hand, projected sampling area could be larger!)
                const float view_correction = 1.0f + VIEW_CORRECTION_SCALE * (1.0f - dot(currentViewDir, currentNormal));
                total_ao += cos_angle * distance_intensity * view_correction;
#endif
                total_ao += cos_angle * distance_intensity;
        }

        return float2(max(0.0f, 1.0f - total_ao), numSamples);
        //return saturate(dot(currentViewDir, currentNormal));
}


/** The mrt shader for screen space ambient occlusion
*/
pixel main(fragment IN, 
                   uniform sampler2D colors,
                   uniform sampler2D positions,
                   uniform sampler2D normals,
                   uniform sampler2D noiseTexture,
                   uniform float2 samples[NUM_SAMPLES],
                   uniform sampler2D oldTex,
                   const uniform float4x4 oldModelViewProj,
                   uniform float maxDepth,
                   uniform float temporalCoherence,
                   uniform float3 eyePos,
                   uniform float3 bl,
                   uniform float3 br,
                   uniform float3 tl,
                   uniform float3 tr
                   )
{
        pixel OUT;

        float4 norm = tex2D(normals, IN.texCoord.xy);
        float3 normal = normalize(norm.xyz);

        // a constant ambient term
        const float amb = norm.w;
        // the w coordinate from the persp. projection
        float w = norm.w;
        // the current world position
        const float4 centerPosition = tex2D(positions, IN.texCoord.xy);
        
        /*
        /// the current view direction
        float3 viewDir = normalize(IN.view);
        const float eyeDepth = tex2D(colors, IN.texCoord.xy).w;
        float4 centerPosition2;
        centerPosition2.xyz = eyePos - view2 * eyeDepth;
*/

        // the current depth
        const float currentDepth = centerPosition.w;

        //const float2 ao = ssao(IN, positions, noiseTexture, samples, normal, centerPosition, w, viewDir, eyePos);
        const float2 ao = ssao(IN, positions, noiseTexture, samples, normal, centerPosition, w, eyePos, bl, br, tl, tr);
                

        /////////////////
        //-- compute temporally smoothing

        float4 realPos = centerPosition * maxDepth;
        realPos.w = 1.0f;


        ///////////
        //-- reprojection from new frame into old one

        float4 oldPos = mul(oldModelViewProj, realPos);

        const float newDepth = oldPos.z / oldPos.w;

        float2 tex = (oldPos.xy / oldPos.w) * 0.5f + 0.5f;
        float4 oldCol = tex2D(oldTex, tex);

        const float oldDepth = oldCol.w;
        const float depthDif = 1.0f - newDepth / oldDepth;

        float oldWeight = clamp(oldCol.z, 0, temporalCoherence);
        float oldNumSamples = oldCol.y;

        float newWeight;

        float newNumSamples = ao.y;

        if (//(temporalCoherence > 0) &&
                (tex.x >= 0.0f) && (tex.x < 1.0f) && 
                (tex.y >= 0.0f) && (tex.y < 1.0f) && 
                (abs(depthDif) < 1e-4f) 
                // if visibility changed in the surrounding area we have to recompute
                && (oldNumSamples > 0.8f * newNumSamples)
                //&& (oldAvgDepth / newAvgDepth > 0.99)
                )
        {
                // increase the weight for convergence
                newWeight = oldWeight + 1.0f;
                OUT.illum_col.xy = (ao.xy + oldCol.xy * oldWeight) / newWeight;

                //if (!(oldNumSamples > ao.y - 1.5f)) newWeight = 0;
        }
        else
        {       
                OUT.illum_col.xy = ao.xy;
                newWeight = 0;
        }

        OUT.illum_col.z = newWeight;
        OUT.illum_col.w = currentDepth;

        return OUT;
}


pixel combine(fragment IN, 
                          uniform sampler2D colors,
                          uniform sampler2D ssaoTex,
                          uniform sampler2D positions)
{
        pixel OUT;

        float4 col = tex2Dlod(colors, float4(IN.texCoord.xy, 0, 0));
        float4 ao = tex2D(ssaoTex, IN.texCoord.xy);

        OUT.illum_col = col * ao.x;
        //OUT.illum_col = float4(ao.x,ao.x,ao.x, ao.w);
        OUT.illum_col.w = col.w;

        return OUT;
}