source: GTP/trunk/App/Demos/Vis/FriendlyCulling/src/shaders/ssao.cg @ 3221

#include "../shaderenv.h"


////////////////////
// Screen Spaced Ambient Occlusion shader
// based on shader of Alexander Kusternig


#define USE_EYESPACE_DEPTH 1


struct fragment
{
        float2 texCoord: TEXCOORD0; 
        float3 view: TEXCOORD1;
};


struct pixel
{
        float4 illum_col: COLOR0;
};


inline float occlusionPower(float radius, float dist)
{
        return 6.283185307179586476925286766559f * (1.0f - cos(asin(radius / dist)));
}


inline float SqrLen(float3 v)
{
        return v.x * v.x + v.y * v.y + v.z * v.z;
}


inline float2 myreflect(float2 pt, float2 n)
{
        // distance to plane
        float d = dot(n, pt);
        // reflect around plane
        float2 rpt = pt - d * 2.0f * n;

        return rpt;
}


inline float3 Interpol(float2 w, float3 bl, float3 br, float3 tl, float3 tr)
{
        float3 x1 = lerp(bl, tl, w.y);
        float3 x2 = lerp(br, tr, w.y); 
        float3 v = lerp(x1, x2, w.x); 

        return v;
}


// reconstruct world space position
inline float3 ReconstructSamplePos(float eyeSpaceDepth,
                                                                   float2 texcoord, 
                                                                   float3 bl, float3 br, float3 tl, float3 tr)
{
        float3 viewVec = Interpol(texcoord, bl, br, tl, tr);
        float3 samplePos = -viewVec * eyeSpaceDepth;

        return samplePos;
}



/** This shader computes the reprojection and stores 
        the ssao value of the old pixel as well as the
        weight of the pixel in the new frame.
*/
inline float2 temporalSmoothing(float4 worldPos,
                                                                float eyeSpaceDepth,
                                                                float2 texcoord0,
                                                                float3 oldEyePos,
                                                                sampler2D oldTex,
                                                                float4x4 oldModelViewProj,
                                                                sampler2D colors,
                                                                float3 projPos,
                                                                float invW,
                                                                float3 oldbl,
                                                                float3 oldbr,
                                                                float3 oldtl,
                                                                float3 oldtr,
                                                                float3 diffVec
                                                                )
{
        // compute position from old frame for dynamic objects + translational portion
        const float3 translatedPos = diffVec - oldEyePos + worldPos.xyz;


        /////////////////
        //-- reproject into old frame and calculate texture position of sample in old frame

        // note: the old model view matrix only holds the view orientation part
        float4 backProjPos = mul(oldModelViewProj, float4(translatedPos, 1.0f));
        backProjPos /= backProjPos.w;
        
        // fit from unit cube into 0 .. 1
        const float2 oldTexCoords = backProjPos.xy * 0.5f + 0.5f;
        // retrieve the sample from the last frame
        const float4 oldPixel = tex2Dlod(oldTex, float4(oldTexCoords, .0f, .0f));

        // the ssao value in the old frame
        const float ssao = oldPixel.x;

        // calculate eye space position of sample in old frame
        const float oldEyeSpaceDepth = oldPixel.w;

        // vector from eye pos to old sample 
        const float3 viewVec = Interpol(oldTexCoords, oldbl, oldbr, oldtl, oldtr);
        const float invLen = 1.0f / length(viewVec);
        const float projectedEyeSpaceDepth = invLen * length(translatedPos);
        //const float projectedEyeSpaceDepth = length(translatedPos);
        
        const float depthDif = abs(1.0f - oldEyeSpaceDepth / projectedEyeSpaceDepth);

        const float xOffs = 1.0f / 1024.0f;
        const float yOffs = 1.0f / 768.0f;
        const float eps = 1e-6f;

        // the weight of the old value
        float w;

        //////////////
        //-- reuse old value only if it was still valid in the old frame

        if (1
                && (oldTexCoords.x + eps >= xOffs) && (oldTexCoords.x <= 1.0f - xOffs + eps)
                && (oldTexCoords.y + eps >= yOffs) && (oldTexCoords.y <= 1.0f - yOffs + eps)
                && (depthDif <= MIN_DEPTH_DIFF) 
                )
        {
                // pixel valid => retrieve the convergence weight
                w = oldPixel.y;
        }
        else
        {       
                w = 0.0f;
        }

        return float2(ssao, w);
}


/** The ssao shader returning the an intensity value between 0 and 1
        This version of the ssao shader uses the dotproduct between pixel and 
        sample normal as weight.
*/
float3 ssao2(fragment IN,
                         sampler2D colors,
                         sampler2D noiseTex,
                         float2 samples[NUM_SAMPLES],
                         float3 normal,
                         float3 centerPosition,
                         float scaleFactor,
                         float3 bl,
                         float3 br,
                         float3 tl,
                         float3 tr, 
                         float3 viewDir,
                         sampler2D normalTex,
                         float sampleIntensity
                         )
{
        float total_ao = .0f;
        float numSamples = .0f;
        float validSamples = .0f;

        for (int i = 0; i < NUM_SAMPLES; ++ i) 
        {
                const float2 offset = samples[i];

#if 1
                ////////////////////
                //-- add random noise: reflect around random normal vector (rather slow!)

                const float2 mynoise = tex2Dlod(noiseTex, float4(IN.texCoord * 4.0f, 0, 0)).xy;
                const float2 offsetTransformed = myreflect(offset, mynoise);
#else
                const float2 offsetTransformed = offset;
#endif
                // weight with projected coordinate to reach similar kernel size for near and far
                //const float2 texcoord = IN.texCoord.xy + offsetTransformed * scaleFactor + jitter;
                const float2 texcoord = IN.texCoord.xy + offsetTransformed * scaleFactor;

                //if ((texcoord.x <= 1.0f) && (texcoord.x >= 0.0f) && (texcoord.y <= 1.0f) && (texcoord.y >= 0.0f)) ++ numSamples;
                float4 sampleColor = tex2Dlod(colors, float4(texcoord, 0, 0));

                const float3 samplePos = ReconstructSamplePos(sampleColor.w, texcoord, bl, br, tl, tr);
                // the normal of the current sample
                const float3 sampleNormal = tex2Dlod(normalTex, float4(texcoord, 0, 0)).xyz;


                ////////////////
                //-- compute contribution of sample using the direction and angle

                float3 dirSample = samplePos - centerPosition;

                const float sqrLen = max(SqrLen(dirSample), 1e-2f);
                const float lengthToSample = sqrt(sqrLen);
                //const float lengthToSample = max(length(dirSample), 1e-6f);

                dirSample /= lengthToSample; // normalize

                // angle between current normal and direction to sample controls AO intensity.
                float cosAngle = .5f + dot(sampleNormal, -normal) * 0.5f;
                // use binary decision to cull samples that are behind current shading point
                cosAngle *= step(0.0f, dot(dirSample, normal));
        
                const float aoContrib = sampleIntensity / sqrLen;
                //const float aoContrib = (1.0f > lengthToSample) ? occlusionPower(9e-2f, DISTANCE_SCALE + lengthToSample): .0f;

#if 1
                // if surface normal perpenticular to view dir, approx. half of the samples will not count
                // => compensate for this (on the other hand, projected sampling area could be larger!)

                const float viewCorrection = 1.0f + VIEW_CORRECTION_SCALE * max(dot(viewDir, normal), 0.0f);
                total_ao += cosAngle * aoContrib * viewCorrection;
#else
                total_ao += cosAngle * aoContrib;
#endif
                // check if the samples have been valid in the last frame
                validSamples += (1.0f - step(1.0f, lengthToSample)) * sampleColor.x;

                ++ numSamples;
        }

        total_ao /= numSamples;

        return float3(max(0.0f, 1.0f - total_ao), validSamples, numSamples);
}


/** The ssao shader returning the an intensity value between 0 and 1.
        This version of the ssao shader uses the dotproduct between 
        pixel-to-sample direction and sample normal as weight.

    The algorithm works like the following:
        1) Check in a circular area around the current position.
        2) Shoot vectors to the positions there, and check the angle to these positions.
        3) Summing up these angles gives an estimation of the occlusion at the current position.
*/
float3 ssao(fragment IN,
                        sampler2D colors,
                        sampler2D noiseTex,
                        float2 samples[NUM_SAMPLES],
                        float3 normal,
                        float3 centerPosition,
                        float scaleFactor,
                        float3 bl,
                        float3 br,
                        float3 tl,
                        float3 tr, 
                        float3 viewDir,
                        float newWeight,
                        float sampleIntensity,
                        bool isMovingObject
                        )
{
        float total_ao = .0f;
        float validSamples = .0f;
        float numSamples = .0f;

        for (int i = 0; i < NUM_SAMPLES; ++ i) 
        {
                const float2 offset = samples[i];

#if 1
                ////////////////////
                //-- add random noise: reflect around random normal vector 
                //-- (slows down the computation for some reason!)

                float2 mynoise = tex2Dlod(noiseTex, float4(IN.texCoord * 4.0f, 0, 0)).xy;
                const float2 offsetTransformed = myreflect(offset, mynoise);
#else
                const float2 offsetTransformed = offset;
#endif
                // weight with projected coordinate to reach similar kernel size for near and far
                const float2 texcoord = IN.texCoord.xy + offsetTransformed * scaleFactor;

                const float4 sampleColor = tex2Dlod(colors, float4(texcoord, .0f, .0f));
                const float3 samplePos = ReconstructSamplePos(sampleColor.w, texcoord, bl, br, tl, tr);
                

                ////////////////
                //-- compute contribution of sample using the direction and angle

                float3 dirSample = samplePos - centerPosition;

                const float sqrLen = max(SqrLen(dirSample), 1e-2f);
                const float lengthToSample = sqrt(sqrLen);

                dirSample /= lengthToSample; // normalize

                // angle between current normal and direction to sample controls AO intensity.
                const float cosAngle = max(dot(dirSample, normal), .0f);
                const float aoContrib = sampleIntensity / sqrLen;
                //const float aoContrib = (1.0f > lengthToSample) ? occlusionPower(9e-2f, DISTANCE_SCALE + lengthToSample): .0f;

#if 1
                // if surface normal perpenticular to view dir, approx. half of the samples will not count
                // => compensate for this (on the other hand, projected sampling area could be larger!)

                const float viewCorrection = 1.0f + VIEW_CORRECTION_SCALE * max(dot(viewDir, normal), 0.0f);
                total_ao += cosAngle * aoContrib * viewCorrection;
#else
                total_ao += cosAngle * aoContrib;
#endif

                ++ numSamples;

                // check if the samples have been valid in the last frame
                // only mark sample as invalid if in the last / current frame
                // they possibly have any influence on the ao
                const float changeFactor = sampleColor.y;
                const float pixelValid = sampleColor.x;

                // we check if the sample could have been near enough to the current pixel 
                // to have any influence in the current or last frame
                const float tooFarAway = step(0.5f, lengthToSample - changeFactor);
                validSamples = max(validSamples, (1.0f - tooFarAway) * pixelValid);

#ifdef QWQ//USE_GTX
                // we can bail out early and use a minimal #samples)
                // if some conditions are met as long as the hardware supports it
                if (numSamples >= 8)
                {
                        // if the pixel belongs to a static object and all the samples stay valid in the current frame
                        if (!isMovingObject && (validSamples < 1.0f)) break;
                        // if the pixel belongs to a dynamic object but the #accumulated samples for this pixel is sufficiently high 
                        // (=> there was no discontinuity recently)
                        else if (isMovingObject && (newWeight > NUM_SAMPLES * 5)) break;
                }
#endif

        }

        // scale ao contribution
        total_ao /= numSamples;

        return float3(total_ao, validSamples, numSamples);
}



/** The mrt shader for screen space ambient occlusion
*/
pixel main(fragment IN, 
                   uniform sampler2D colors,
                   uniform sampler2D normals,
                   uniform sampler2D noiseTex,
                   uniform float2 samples[NUM_SAMPLES],
                   uniform sampler2D oldTex,
                   uniform float4x4 modelViewProj,
                   uniform float4x4 oldModelViewProj,
                   uniform float temporalCoherence,
                   uniform float3 bl,
                   uniform float3 br,
                   uniform float3 tl,
                   uniform float3 tr,
                   uniform float3 oldEyePos,
                   uniform float3 oldbl,
                   uniform float3 oldbr,
                   uniform float3 oldtl,
                   uniform float3 oldtr,
                   uniform sampler2D attribsTex,
                   uniform float kernelRadius,
                   uniform float sampleIntensity
                   )
{
        pixel OUT;

        //const float3 normal = normalize(tex2Dlod(normals, float4(IN.texCoord, 0 ,0)).xyz);
        const float3 normal = tex2Dlod(normals, float4(IN.texCoord, 0 ,0)).xyz;

        // reconstruct position from the eye space depth
        const float3 viewDir = IN.view;
        const float eyeSpaceDepth = tex2Dlod(colors, float4(IN.texCoord, 0, 0)).w;
        const float4 eyeSpacePos = float4(-viewDir * eyeSpaceDepth, 1.0f);

        float3 diffVec = tex2Dlod(attribsTex, float4(IN.texCoord, 0, 0)).xyz;
        

        ////////////////
        //-- calculcate the current projected posiion (also used for next frame)
        
        float4 projPos = mul(modelViewProj, eyeSpacePos);
        const float invw = 1.0f / projPos.w;
        projPos *= invw;
        float scaleFactor = kernelRadius * invw;

        const float sqrMoveSpeed = SqrLen(diffVec);
        const bool isMovingObject = (sqrMoveSpeed > DYNAMIC_OBJECTS_THRESHOLD);

        
        /////////////////
        //-- compute temporal reprojection

        float2 temporalVals = temporalSmoothing(eyeSpacePos, eyeSpaceDepth, IN.texCoord, oldEyePos,
                                                oldTex, oldModelViewProj, 
                                                                                        colors, 
                                                                                        projPos.xyz, 
                                                                                        invw, 
                                                                                        oldbl, oldbr, oldtl, oldtr,
                                                                                        diffVec
                                                                                        );

        const float oldSsao = temporalVals.x;
        float oldWeight = temporalVals.y;
        
        float3 ao;

        // cull background note: this should be done with the stencil buffer
        if (eyeSpaceDepth < 1e10f)
        {
                ao = ssao(IN, colors, noiseTex, samples, normal, eyeSpacePos.xyz, scaleFactor, bl, br, tl, tr, normalize(viewDir), oldWeight, sampleIntensity, isMovingObject);
                //ao = ssao2(IN, colors, noiseTex, samples, normal, eyeSpacePos.xyz, scaleFactor, bl, br, tl, tr, normalize(viewDir), normals, sampleIntensity);
        }
        else
        {
                 ao = float3(1.0f, 1.0f, 1.0f);
        }

        
        ///////////
        //-- check if we have to reset pixel because one of the sample points was invalid
        //-- only do this if the current pixel does not belong to a moving object

        // the weight equals the number of sampled shot in this pass
        const float newWeight = ao.z;

        const float completelyResetThres = 4.0f;
        const float partlyResetThres = 1.0f;
        
        if (!isMovingObject)
        {
                if (ao.y > completelyResetThres) 
                        oldWeight = .0f; 
                else if (ao.y > partlyResetThres)
                        oldWeight = min(oldWeight, 4.0f * newWeight);
        }

        // the new weight for the next frame
        const float combinedWeight = clamp(newWeight + oldWeight, .0f, temporalCoherence);

        //////////
        //-- blend ao between old and new samples (and avoid division by zero)
        OUT.illum_col.x = (ao.x * newWeight + oldSsao * oldWeight) / max(1e-6f, newWeight + oldWeight);

        OUT.illum_col.z = SqrLen(diffVec);
        OUT.illum_col.y = combinedWeight;
        OUT.illum_col.w = eyeSpaceDepth;

        return OUT;
}