source: GTP/trunk/App/Demos/Vis/FriendlyCulling/src/shaders/ssao.cg @ 2904

#include "../shaderenv.h"

////////////////////
// Screen Spaced Ambient Occlusion shader
// based on shader of Alexander Kusternig


struct fragment
{
         // normalized screen position
        float4 pos: WPOS;
        float2 texCoord: TEXCOORD0; 
        float3 view: TEXCOORD1;
};


struct pixel
{
        float4 illum_col: COLOR0;
};


float2 myreflect(float2 pt, float2 n)
{
        // distance to plane
        float d = dot(n, pt);
        // reflect around plane
        float2 rpt = pt - d * 2.0f * n;

        return rpt;
}



/** The ssao shader returning the an intensity value between 0 and 1
*/
float2 ssao(fragment IN,
                   uniform sampler2D positions,
                   uniform sampler2D noiseTexture,
                   uniform float2 samples[NUM_SAMPLES],
                   uniform float3 currentNormal,
                   uniform float4 centerPosition
                   //,uniform float3 currentViewDir
                   )
{
        // the w coordinate from the persp. projection
        float w = centerPosition.w;

        // Check in a circular area around the current position.
        // Shoot vectors to the positions there, and check the angle to these positions.
        // Summing up these angles gives an estimation of the occlusion at the current position.

        float total_ao = 0.0;
        float numSamples = 0;

        for (int i = 0; i < NUM_SAMPLES; ++ i) 
        {
                const float2 offset = samples[i];

#if 1
                ////////////////////
                // add random noise: reflect around random normal vector (warning: slow!)
                float2 mynoise = tex2D(noiseTexture, IN.texCoord.xy).xy;
                const float2 offsetTransformed = myreflect(offset, mynoise);
#else
                const float2 offsetTransformed = offset;
#endif
                // weight with projected coordinate to reach similar kernel size for near and far
                float2 texcoord = IN.texCoord.xy + offsetTransformed * AREA_SIZE * w;

                if ((texcoord.x <= 1.0f) && (texcoord.x >= 0.0f) && (texcoord.y <= 1.0f) && (texcoord.y >= 0.0f))
                        ++ numSamples;

                // sample downsampled texture in order to speed up texture accesses
                float3 sample_position = tex2Dlod(positions, float4(texcoord, 0, 1)).xyz;
                //float3 sample_position = tex2D(positions, texcoord).xyz;

                float3 vector_to_sample = sample_position - centerPosition.xyz;
                const float length_to_sample = length(vector_to_sample);

                float3 direction_to_sample = vector_to_sample / length_to_sample;

                // angle between current normal and direction to sample controls AO intensity.
                const float cos_angle = max(dot(direction_to_sample, currentNormal), 0.0f);

                // distance between current position and sample position controls AO intensity.
                const float distance_intensity = 
                        (SAMPLE_INTENSITY * DISTANCE_SCALE) / (DISTANCE_SCALE + length_to_sample * length_to_sample);

                // if surface normal perpenticular to view dir, approx. half of the samples will not count
                // => compensate for this (on the other hand, projected sampling area could be larger!)
                //const float view_correction = 1.0f + VIEW_CORRECTION_SCALE * (1.0f - dot(currentViewDir, currentNormal));
                //total_ao += cos_angle * distance_intensity * view_correction;

                total_ao += cos_angle * distance_intensity;

                //total_ao /= j;
        }

        return float2(max(0.0f, 1.0f - total_ao), numSamples);
        //return saturate(dot(currentViewDir, currentNormal));
}


/** The mrt shader for screen space ambient occlusion
*/
pixel main(fragment IN, 
                   uniform sampler2D colors,
                   uniform sampler2D positions,
                   uniform sampler2D normals,
                   uniform sampler2D noiseTexture,
                   uniform float2 samples[NUM_SAMPLES],
                   uniform sampler2D oldTex,
                   const uniform float4x4 oldModelViewProj,
                   uniform float maxDepth,
                   uniform float temporalCoherence
                   )
{
        pixel OUT;

        float4 norm = tex2D(normals, IN.texCoord.xy);
        
        // the ambient term
        const float amb = norm.w;

        // expand normal
        float3 normal = normalize(norm.xyz);
        
        /// the current view direction
        //float3 viewDir = normalize(IN.view);

        // the current world position
        const float4 centerPosition = tex2D(positions, IN.texCoord.xy);
        
        // the current color
        const float4 currentCol = tex2D(colors, IN.texCoord.xy);
        const float currentDepth = currentCol.w;

        const float2 ao = ssao(IN, positions, noiseTexture, samples, normal, centerPosition);//, viewDir);
                

        /////////////////
        //-- compute temporally smoothing

        float4 realPos = centerPosition * maxDepth;
        realPos.w = 1.0f;

        // reproject
        float4 oldPos = mul(oldModelViewProj, realPos);

        const float newDepth = oldPos.z / oldPos.w;

        float2 tex = (oldPos.xy / oldPos.w) * 0.5f + 0.5f;
        float4 oldCol = tex2D(oldTex, tex);

        const float oldDepth = oldCol.w;
        const float depthDif = 1.0f - newDepth / oldDepth;

        float oldWeight = clamp(oldCol.z, 0, temporalCoherence);
        float oldNumSamples = oldCol.y;

        float newWeight;

        if (//(temporalCoherence > 0) &&
                (tex.x >= 0.0f) && (tex.x < 1.0f) && 
                (tex.y >= 0.0f) && (tex.y < 1.0f) && 
                (abs(depthDif) < 1e-3f) 
                && (oldNumSamples > ao.y - 1.5f) // check if something happened in the surrounding area
                )
        {
                // increase the weight for convergence
                newWeight = oldWeight + 1.0f;

                //OUT.illum_col = (float4)ao * expFactor + oldCol.x * (1.0f - expFactor);
                OUT.illum_col.xy = (ao.xy + oldCol.xy * oldWeight) / newWeight;

                //if (!(oldNumSamples > ao.y - 1.5f)) newWeight = 0;
        }
        else
        {
                OUT.illum_col.xy = ao.xy;
                newWeight = 0;
        }


        //OUT.illum_col.y = ao.y;
        OUT.illum_col.z = newWeight;
        OUT.illum_col.w = currentDepth;

        return OUT;
}


pixel combine(fragment IN, 
                          uniform sampler2D colors,
                          uniform sampler2D ssaoTex)
{
        pixel OUT;

        float4 col = tex2Dlod(colors, float4(IN.texCoord.xy, 0, 0));
        float4 ao = tex2D(ssaoTex, IN.texCoord.xy);

        OUT.illum_col = col * ao.x;
        //OUT.illum_col = (float4)ao.x;

        OUT.illum_col.w = ao.w;

        return OUT;
}