// this is a slighty modified version of the nvidia ocean.fx shader

float4x4 worldMatrix : World;	           	// World or Model matrix
float4x4 wvpMatrix : WorldViewProjection;	// Model*View*Projection
float4x4 worldViewMatrix : WorldView;
float4x4 viewInverseMatrix : ViewInverse;

float time : Time;
bool forRaytracer = false;

float3 fSceneDimensions;

texture normalMap : Normal;

texture cubeMap : Environment;

texture terrainTex;

float FarPlaneMinusNearPlane; // Distance of the far plane minus distance of the near plane.

sampler2D normalMapSampler = sampler_state
{
	Texture = <normalMap>;
	MagFilter = Linear;	
	MinFilter = Linear;
	MipFilter = Linear;
};

samplerCUBE envMapSampler = sampler_state
{
	Texture = <cubeMap>;
	MinFilter = Linear;
	MagFilter = Linear;
	MipFilter = Linear;
    AddressU = Clamp;
    AddressV = Clamp;
};


sampler2D terrainSampler = sampler_state
{
	Texture = <terrainTex>;
	minfilter = Linear; 
    mipfilter = Linear; 
    magfilter = Linear;
    addressu = BORDER;
    addressv = BORDER;
    addressw = BORDER;
};

float bumpHeight = 0.5;
float2 textureScale = {25.60, 12.80 };
float2 bumpSpeed = { -0.1, 0.1 };
float fresnelBias = 0.5;
//float fresnelPower = 4.0;
float fresnelPower = 12.0;
float hdrMultiplier = 3.0;
//float4 deepColor : Diffuse = {0.0f, 0.0f, 0.1f, 1.0f};
//float4 shallowColor : Diffuse = {0.0f, 0.5f, 0.5f, 1.0f};
float4 deepColor : Diffuse;
float4 shallowColor : Diffuse;
float4 reflectionColor : Specular = {0.5f, 0.5f, 0.5f, 1.0f};
float reflectionAmount = 1.0f;
float waterAmount = 1.0f;
float waveAmp = 0.0;
float waveFreq = 0.1;

struct a2v {
	float4 Position : POSITION;   // in object space
	float2 TexCoord : TEXCOORD0;
	float2 terrainCoord : TEXCOORD1;
	float3 Tangent  : TEXCOORD2;
	float3 Binormal : TEXCOORD3;
	float3 Normal   : NORMAL;
	
};

struct v2f {
	float4 Position  : POSITION;  // in clip space
	float2 TexCoord  : TEXCOORD0;
	float3 TexCoord1 : TEXCOORD1; // first row of the 3x3 transform from tangent to cube space
	float3 TexCoord2 : TEXCOORD2; // second row of the 3x3 transform from tangent to cube space
	float3 TexCoord3 : TEXCOORD3; // third row of the 3x3 transform from tangent to cube space

	float2 bumpCoord0 : TEXCOORD4;
	float2 bumpCoord1 : TEXCOORD5;
	float2 bumpCoord2 : TEXCOORD6;
	
	float3 eyeVector  : TEXCOORD7;
	
	float4 pos2 : COLOR0;
	float4 terrainCoord : COLOR1;
};

struct v2fdepth {
	float4 HPosition : POSITION;
    float4 texCoord	: TEXCOORD0;	
};

struct PS_OUTPUT
{
    float4 diffuse : COLOR0;
};

struct pixelOutput
{
	float4 color				: COLOR;
};


struct depthVertexInput {
    float4 position				: POSITION;
    float4 texCoord				: TEXCOORD0;
};

struct depthVertexOutput {
    float4 HPosition 			: POSITION;
    float4 texCoord				: TEXCOORD0;
};

// wave functions

struct Wave {
  float freq;  // 2*PI / wavelength
  float amp;   // amplitude
  float phase; // speed * 2*PI / wavelength
  float2 dir;
};

#define NWAVES 2
Wave wave[NWAVES] = {
	{ 1.0, 1.0, 0.5, float2(-1, 0) },
	{ 2.0, 0.5, 1.3, float2(-0.7, 0.7) }	
};

float evaluateWave(Wave w, float2 pos, float t)
{
  return w.amp * sin( dot(w.dir, pos)*w.freq + t*w.phase);
}

// derivative of wave function
float evaluateWaveDeriv(Wave w, float2 pos, float t)
{
  return w.freq*w.amp * cos( dot(w.dir, pos)*w.freq + t*w.phase);
}

v2f BumpReflectWaveVS(a2v IN,
					  uniform float4x4 WorldViewProj,
					  uniform float4x4 World,
					  uniform float4x4 ViewIT,
					  uniform float BumpScale,
					  uniform float2 textureScale,
					  uniform float2 bumpSpeed,
					  uniform float time,
					  uniform float waveFreq,
					  uniform float waveAmp
                	  )
{
	v2f OUT;

    wave[0].freq = waveFreq;
    wave[0].amp = waveAmp;

    wave[1].freq = waveFreq*2.0;
    wave[1].amp = waveAmp*0.5;

    float4 P = IN.Position;

	// sum waves	
	
	float ddx = 0.0, ddy = 0.0;
	for(int i=0; i<NWAVES; i++) {
    	//P.y += evaluateWave(wave[i], P.xz, time);
    	float deriv = evaluateWaveDeriv(wave[i], P.xz, time);
    	ddx += deriv * wave[i].dir.x;
    	ddy += deriv * wave[i].dir.y;
    }

	P.y = 0.5f;

	// compute tangent basis
    float3 B = float3(1, ddx, 0);
    float3 T = float3(0, ddy, 1);
    float3 N = float3(-ddx, 1, -ddy);

	OUT.Position = mul(P, WorldViewProj);
	
	// pass texture coordinates for fetching the normal map
	OUT.TexCoord.xy = IN.TexCoord*textureScale;

	time = fmod(time, 100.0);
	OUT.bumpCoord0.xy = IN.TexCoord*textureScale + time*bumpSpeed;
	OUT.bumpCoord1.xy = IN.TexCoord*textureScale*2.0 + time*bumpSpeed*4.0;
	OUT.bumpCoord2.xy = IN.TexCoord*textureScale*4.0 + time*bumpSpeed*8.0;

	// compute the 3x3 tranform from tangent space to object space
	float3x3 objToTangentSpace;
	// first rows are the tangent and binormal scaled by the bump scale
	objToTangentSpace[0] = BumpScale * normalize(T);
	objToTangentSpace[1] = BumpScale * normalize(B);
	objToTangentSpace[2] = normalize(N);

	OUT.TexCoord1.xyz = mul(objToTangentSpace, World[0].xyz);
	OUT.TexCoord2.xyz = mul(objToTangentSpace, World[1].xyz);
	OUT.TexCoord3.xyz = mul(objToTangentSpace, World[2].xyz);
	
	//for raytracer:
	if(forRaytracer) {
		OUT.pos2 = mul(IN.Position, worldViewMatrix );
	} else {
		OUT.pos2.xyzw = 0;
	}
	

	// compute the eye vector (going from shaded point to eye) in cube space
	float4 worldPos = mul(P, World);
	OUT.eyeVector = ViewIT[3] - worldPos; // view inv. transpose contains eye position in world space in last row
	OUT.terrainCoord.xy = IN.TexCoord;
	OUT.terrainCoord.zw = 0;
	return OUT;
}

// Pixel Shaders

float4 OceanPS20(v2f IN,
				 uniform sampler2D NormalMap,
				 uniform samplerCUBE EnvironmentMap,
				 uniform sampler2D terrainSamp, 
				 uniform half4 deepColor,
				 uniform half4 shallowColor,
				 uniform half4 reflectionColor,
				 uniform half4 reflectionAmount,
				 uniform half4 waterAmount,
				 uniform half fresnelPower,
				 uniform half fresnelBias,
				 uniform half hdrMultiplier
				 ) : COLOR
{
	// sum normal maps
    half4 t0 = tex2D(NormalMap, IN.bumpCoord0.xy)*2.0-1.0;
    half4 t1 = tex2D(NormalMap, IN.bumpCoord1.xy)*2.0-1.0;
    half4 t2 = tex2D(NormalMap, IN.bumpCoord2.xy)*2.0-1.0;
    half3 N = t0.xyz + t1.xyz + t2.xyz;

    half3x3 m; // tangent to world matrix
    m[0] = IN.TexCoord1;
    m[1] = IN.TexCoord2;
    m[2] = IN.TexCoord3;
    half3 Nw = mul(m, N.xyz);
    Nw = normalize(Nw);

	// reflection
    float3 E = normalize(IN.eyeVector);
    half3 R = reflect(-E, Nw);

    half4 reflection = texCUBE(EnvironmentMap, R);
    // hdr effect (multiplier in alpha channel)
    reflection.rgb *= (1.0 + reflection.a*hdrMultiplier);

	// fresnel - could use 1D tex lookup for this
    half facing = 1.0 - max(dot(E, Nw), 0);
    half fresnel = fresnelBias + (1.0-fresnelBias)*pow(facing, fresnelPower);

    half4 waterColor = lerp(deepColor, shallowColor, facing);

	float4 result = waterColor*waterAmount + reflection*reflectionColor*reflectionAmount*fresnel;
	
	if (forRaytracer) {
		result.a = (float) ( length( IN.pos2.xyz ) );
	} else {
		float3 terr = tex2D(terrainSampler, IN.terrainCoord.xy);
		result.a = (float)(1.0f - (float)terr.x);
	}
	
	return result;
}

/*PS_OUTPUT depthPS(v2fdepth IN)
{
	PS_OUTPUT OUT;
	float depth = IN.texCoord.a;
	OUT.diffuse = float4(depth, depth, depth, depth);
	return OUT;
}*/

depthVertexOutput DepthPassVS(depthVertexInput IN) 
{
    depthVertexOutput OUT;
    float4 P = IN.position;
    
    P.y = 0.5f;
        
	// sum waves	
	
	/*float ddx = 0.0, ddy = 0.0;
	for(int i=0; i<NWAVES; i++) {
    	P.y += evaluateWave(wave[i], P.xz, time);
    }*/
    
    //float4 vertexpos = float4(IN.position.xyz, 1.0);
    float4 vertexpos = P;
	float4 eyespace = mul(vertexpos, wvpMatrix);
	OUT.HPosition = eyespace;
	float tempDepth = saturate(eyespace.z/FarPlaneMinusNearPlane);
	IN.texCoord.a = tempDepth;
	OUT.texCoord = IN.texCoord;
	return OUT;
}

pixelOutput DepthPassPS(depthVertexOutput IN)
{
	pixelOutput OUT;
	float depth = IN.texCoord.a;
	OUT.color = float4(depth, depth, depth, depth);
	return OUT;
}

technique PS20 
{
	pass p0 
	{
		VertexShader = compile vs_3_0 BumpReflectWaveVS(wvpMatrix, worldMatrix, viewInverseMatrix,
                                                        bumpHeight, textureScale, bumpSpeed, time,
                                                        waveFreq, waveAmp);
		
		PixelShader = compile ps_3_0 OceanPS20(normalMapSampler, envMapSampler, terrainSampler, 
                                               deepColor, shallowColor, reflectionColor, reflectionAmount, waterAmount,
                                               fresnelPower, fresnelBias, hdrMultiplier);
	}
}

technique PS20_Depth
{
	pass p0 
	{
		VertexShader = compile vs_3_0 DepthPassVS();
		
		PixelShader = compile ps_3_0 DepthPassPS();
	}
}